Plik / Aplikacja odpalana ze skrótu klawiaturowego z poziomu folderu.   strona główna:
A po co ten Excel ;-)
 
No właśnie :-) Często do pracy używam pewnego pliku xls. Nie jest on włączony zawsze ale nieraz by sie przydało żeby był. No i   
właśnie kiedy by się tak przydał to musz minimalizować wszystko natenczas włączone i odpalać mój plik. Trochu to długotrwałe  
i mało wygodne szukam wiec sposobu na uruchomienie mojego pliku ze skrótu klawiaturowego który mgółbym wykorzystać dosłownie  
w każdej chwili. I to będzie właśnie naszym zadaniem. :-)  
 
A wiec... Potrzebna nam procedura którą odpalimy z naszego pliku, która... No właśnie co miałaby zrobić taka procedura :-)  
Okazuje się że cel osiągniemy tworząc ukryty skrót na pulpicie określając jego włąściwość Hotkey. :-)  
 
 
Public Declare Function SetFileAttributes _  
    Lib "kernel32" _  
    Alias "SetFileAttributesA" ( _  
        ByVal lpFileName As String, _  
        ByVal dwFileAttributes As Long) _  
    As Long  
 
Const FILE_ATTRIBUTE_HIDDEN = &H2  
 
Sub UtworzSkrotDoPlikuZHotKey()  
    Dim objShell As Object, objShellLink As Object  
    Dim strShortcutName As String  
    Dim strDesktop As String  
      
    Set objShell = CreateObject("WScript.Shell")  
    strDesktop = objShell.SpecialFolders("Desktop")  
    strShortcutName = strDesktop & "\" & ThisWorkbook.Name & ".lnk"  
      
    Set objShellLink = objShell.CreateShortcut(strShortcutName)  
    With objShellLink  
        .TargetPath = ThisWorkbook.FullName  
        .WindowStyle = 1  
        .Hotkey = "Ctrl+Alt+e"  
        .IconLocation = Application.Path & "\EXCEL.EXE, 0"  
        .Description = "Skrót do " & ThisWorkbook.Name  
        .WorkingDirectory = strDesktop  
        .Save  
    End With  
      
    SetFileAttributes strShortcutName, FILE_ATTRIBUTE_HIDDEN  
      
    Set objShellLink = Nothing  
    Set objShell = Nothing  
End Sub  
 
TargetPath - to miejsce zapisu sktóru  
WindowStyle - styl okna w którym ma si uruchomic nasz plik.   WindowStyle Property
Hotkey - "cała magia" w tej właściwości. Zasady tworzenia ciągu pod linkiem do msdn (z prawej)   Hotkey Property
IconLocation - przypisałem ikon Excel.exe ale skrót i tak zamieżam ukryć wiec można by to pominąć   IconLocation Property
WorkingDirectory - miejsce z którego sktór "startuje"   WorkingDirectory Property
 
SetFileAttributes (API) żeby nadać skrótowi atrybut "ukryty"  
 
Może dla wielu będzie to żadna nowość jednak ja wcześniej o tym nie wiedziałem a uważam że zabawka całkiem przydatna :-)